Endpoint

How to use this SPARQL endpoint

The knowledge graphs describing the 3D models of the musical instruments and Montecastelli Pisano are modelled according to the Narrative Ontology.

For this reason, classes and properties used in this endpoint follow the Narrative Ontology data model. To understand how entities are structured and how to properly write SPARQL queries, please refer to the official Narrative Ontology documentation.

📖 Documentation: https://dlnarratives.eu/ontology

SPARQL query examples

Below you can find some example SPARQL queries that can be executed on this endpoint to explore the data.

1. Retrieve the titles of the narratives and the link to the story maps

PREFIX narra:  <https://dlnarratives.eu/ontology#>
PREFIX ecrm:   <http://erlangen-crm.org/current/>
PREFIX rdfs:   <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?narrativeTitle ?link
FROM <urn:x-arq:UnionGraph>
WHERE {
    ?event narra:partOfNarrative ?narrative .
    ?narrative rdfs:label ?narrativeTitle .
    ?narrative ecrm:P48_has_preferred_identifier ?link .
}
ORDER BY ?narrativeTitle
  

2. Retrieve the 3D models and their annotations

PREFIX rdf:    <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX narra:  <https://dlnarratives.eu/ontology#>
PREFIX ecrm:   <http://erlangen-crm.org/current/>
PREFIX rdfs:   <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?narrativeTitle ?model3D
FROM <urn:x-arq:UnionGraph>
WHERE {
    ?event narra:partOfNarrative ?narrative .
    ?narrative rdfs:label ?narrativeTitle .
    ?model3D a <http://erlangen-crm.org/current/E36_visual_item> .
    ?model3D ecrm:P67_refers_to ?event .
}
ORDER BY ?narrativeTitle
  

3. Retrieve the Wikidata entites in all the narratives

PREFIX rdf:    <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX narra:  <https://dlnarratives.eu/ontology#>
PREFIX ecrm:   <http://erlangen-crm.org/current/>
PREFIX rdfs:   <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?entitiesLabel ?wikidataLink
FROM <urn:x-arq:UnionGraph>
WHERE {
    ?event narra:partOfNarrative ?narrative .
    ?event narra:hasWikidataEntity ?wikidataLink.
    ?wikidataLink ecrm:P1_is_identified_by ?entitiesAppellation .
  ?entitiesAppellation ecrm:P3_has_note ?entitiesLabel
}